Mysql 数据库定时备份任务脚本程序
Mysql 定时备份脚本 + 注释说明在批处理中，段注释有一种比较常用的方法：
goto start
= 可以是多行文本，可以是命令
= 可以包含重定向符号和其他特殊字符
= 只要不包含 :start 这一行，就都是注释
:start
另外，还有 其他各种注释形式，比如：
1、:: 注释内容（第一个冒号后也可以跟任何一个非字母数字的字符）
2、rem 注释内容（不能出现重定向符号和管道符号）
3、echo 注释内容（不能出现重定向符号和管道符号）〉nul
4、if not exist nul 注释内容（不能出现重定向符号和管道符号）
5、:注释内容（注释文本不能与已有标签重名）
6、%注释内容%（可以用作行间注释，不能出现重定向符号和管道符号）
7、goto 标签 注释内容（可以用作说明goto的条件和执行内容）
8、:标签 注释内容（可以用作标签下方段的执行内容）
@echo off
rem 设置MySql数据库的连接信息
set host=127.0.0.1
set port=3306
set user=root
set pass=12345678
rem 设置要备份MySql数据库名称
set dbname=zhmysql
rem 获取当天的日期格式，例如：20200919
set backup_date=%Date:~0,4%%Date:~5,2%%Date:~8,2%
rem 设置备份文件的路径
set backupfile=D:\mysql_db_bak
rem 使用mysqldump对指定的MySql进行备份,注意路径中有空格的要加上双引号
echo 启动数据库备份脚步中.....
"D:\mysql\bin\mysqldump" -h%host% -P%port% -u%user% -p%pass% -c --add-drop-table %dbname% > %backupfile%\%dbname%-%backup_date%.sql
rem GnuWin32-zip打包备份的sql文件
echo 导出完毕，数据压缩中.....
"C:\Program Files\WinRAR\WinRAR.exe" a %backupfile%\%dbname%-%backup_date%.zip %backupfile%\%dbname%-%backup_date%.sql
echo 删除已压缩的备份文件中......
del %backupfile%\%dbname%-%backup_date%.sql
rem 删除过期文件，这里是超过90天就删除
forfiles /p %backupfile% /s /m *.zip /d -90 /c "cmd /c del @file /f"正文到此结束
相关文章
该篇文章的评论功能已被站长关闭